OOQL language user

OBEROn user


define - create new user definition

  user define   AdminName {User_DefineOption} [force];

clone - duplicate a user and set the properties for the new instance

  user clone  AdminName define AdminName {User_EditOption} [force];

edit - update the user properties

  user edit   AdminName {User_EditOption} [force];

show - print the user properties

  user show   AdminName [User_GetOption] [Token_Option] [ExportFile_Option] ;

select - extract users on the base of query filters

  user select AdminPatternList {Filter_Option} [User_GetOption]
                                     [Token_Option] [ExportFile_Option] ;

undefine - remove a user from the database [internal mail messages, saved queries, objectgroups
                       and views related to this user will be removed ]

  user undefine AdminName [ moveto AdminName ] ;


User_DefineOption
description GenericValue
application AdminName
image  FileName
imagedata GenericString
address GenericValue
telephone GenericValue
fax GenericValue
language GenericString
objectspace AdminName
localarea AdminName
metricsystem AdminName
[! / not] superuser
email  User_EmailOption { User_EmailOption }
password User_PasswordOption { User_PasswordOption }
systemaccess { User_SystemAccessFlags { , User_SystemAccessFlags } }
adminaccess { User_AdminAccessFlags { , User_AdminAccessFlags } }
basicaccess { User_BasicAccessFlags { , User_BasicAccessFlags } }
assignment  AdminName { AdminName }
team  AdminName { AdminName }
[! /not] hidden

User_EditOption
name AdminName
description GenericValue
application AdminName
svnrev NUMBER
image  FileName
imagedata GenericString
address GenericValue
telephone GenericValue
fax GenericValue
objectspace AdminName
localarea AdminName
metricsystem AdminName
language GenericString
[! / not] superuser
email  User_EmailOption { User_EmailOption }
password User_PasswordOption { User_PasswordOption }
systemaccess { User_SystemAccessFlags { , User_SystemAccessFlags } }
adminaccess { User_AdminAccessFlags { , User_AdminAccessFlags } }
basicaccess { User_BasicAccessFlags { , User_BasicAccessFlags } }
assignment  Edit_Operator   AdminName { Edit_Operator   AdminName }
team  Edit_Operator   AdminName { Edit_Operator   AdminName }
[! /not] hidden

User_EmailOption
address GenericValue
external
internal
both

User_PasswordOption
value GenericValue
none
disabled
enabled
expired
active

User_SystemAccessFlags
everything
nothing
[! / not] objectspace
[! / not] filespace
[! / not] localarea
   
User_AdminAccessFlags
everything
nothing
[! / not] field
[! / not] class
[! / not] linktype
[! / not] user
[! / not] team
[! / not] assignment
[! / not] filetype
[! / not] program
[! / not] webservice
[! / not] lifecycle
[! / not] workflow
[! / not] menu
[! / not] command
[! / not] form
[! / not] view
[! / not] autonumber
[! / not] query
[! / not] graph
[! / not] metricsystem
[! / not] unitmeasure
[! / not] feature
[! / not] dictionary
[! / not] dump
   
User_BasicAccessFlags
everything
nothing
[! / not] create
[! / not] clone
[! / not] changespace
[! / not] changeclass
[! / not] changename
[! / not] changeholder
[! / not] changelifecycle
[! / not] edit
[! / not] undo
[! / not] read
[! / not] fileput
[! / not] fileget
[! / not] filerename
[! / not] filedelete
[! / not] addlinkto
[! / not] addlinkfrom
[! / not] removelinkto
[! / not] removelinkfrom
[! / not] lock
[! / not] unlock
[! / not] progress
[! / not] regress
[! / not] revise
[! / not] execute
[! / not] delegate
[! / not] revoke
[! / not] destroy

User_GetOption
get [User_GetBasicOption]
   
  User_GetBasicOption
  { User_GetBasicToken [as IDENTIFIER] { User_GetBasicToken [as IDENTIFIER] } }
  User_GetBasicToken [as IDENTIFIER]
     
    User_GetBasicToken
    Common_GetBasicOption  
    address  
    telephone  
    fax  
    email  
    mailtype  
    password  
    active  
    enabled  
    superuser  
    language  
    objectspace [. ObjectSpace_GetBasicOption]
    localarea [. LocalArea_GetBasicOption]
    metricsystem [. MetricSystem_GetBasicOption]
    lastaccess  
    systemaccess  
    adminaccess  
    basicaccess  
    assignment [. Assignment_GetBasicOption]
    assignment[] [. Assignment_GetBasicOption]
    assignment[ AdminName ]  
    ownassignment [. Assignment_GetBasicOption]
    ownassignment[] [. Assignment_GetBasicOption]
    ownassignment[ AdminName ]  
    team [. Team_GetBasicOption]
    team[] [. Team_GetBasicOption]
    team[ AdminName ]  
    ownteam [. Team_GetBasicOption]
    ownteam[] [. Team_GetBasicOption]
    ownteam[ AdminName ]  


KEYWORDs
address the user personal address
adminaccess access rights to manage administration objects
application the associated application menu
assignment roles assigned to the user (includes those inherited from teams)
basicaccess basic access rights for object instance operations
description the user description (usually the Full Name)
email the user email address
email specifies the user email options:
address the user email address
internal mail sent by the internal mail
external mail sent by the default smtp host
both mail sent both internally and externally
everything enables all access rights of the same group
fax the user fax number
force this flag allows to ignore errors during the creation/update (for example, the assigments the teams, default objecspace / localarea not yet defined)
hidden administration hidden objects are not visible/usable
image local path for the user icon to upload
imagedata base64 code for the user icon
language the default user language for UI label translation
lastaccess timestamp of the last user login
localarea default localarea used to store files uploaded by the user into a filespace (if supported)
mailtype the user email type ( internal / external / both )
moddate last modification date
moveto if specified, reasigns all associated object/link instances to the specified user, otherwise you will get an error if the user is the holder of objects or links
name the user name (OBEROn account username)
nothing disables all access rights of the same group
objectspace default objectspace used to create objects when not directly specified
ownassignment roles assigned directly to the user (excludes those inherited from teams)
ownteam teams to which the user is directly associated (excludes the super-teams)
password the user login password (OBEROn account password)
password
value the user login password
none empty password
active the user access is currently allowed (password is valid)
expired the password is expired - access disabled
enabled user is enabled
disabled user is disabled
superuser user with special access rights (enabled to perform any administrative actions)
svnrev SVN repository revision number
systemaccess access rights to manage infrastructural objects (objectspace,filespace...)
team teams to which the user is associated (includes the super-teams)
telephone the user telephone number


SAMPLES

user define "name.surname" description "Name Surname" address "Oxford street" telephone "+094347783" fax "+094073190" objectspace "OS01" localarea "LA02"
adminaccess { linktype, assignment, team }
basicaccess { removelinkto, execute }
systemaccess { everything }
password value "pwd1" enabled active email address "name.surname@gmail.com" both

user define 'User2' description "desc user2" address "London Avenue" telephone "+33092393" fax "+3300009" localarea LA01
adminaccess { linktype, assignment, team }
basicaccess { removelinkto, execute }
systemaccess { nothing }
password value "pwd2" enabled active email address "user2@yahoo.es" both;

user clone User2 define User3 description "desc user3" password value "pwd3" ;

user clone "name.surname" define NewUser address "via Roma 23, Milan" objectspace OS02 localarea LA03 basicaccess { !addlinkto ,!removelinkto, !execute } team TM1 TM4;

user edit "name.surname" basicaccess { everything ,!destroy } team add TM0 assignment add AS01;

user show "name.surname" get { name description localarea.{host description} objectspace.{name id description} } token { "|" ";" ","};

user show "name.surname" token xml;

user show User5 get { team[].{name description} ownteam.{ name subteam } } token { "|" ";" "," "-" } ;

user show NewUser get { description basicaccess adminaccess } token { "|" ";" } ;

user select n*,N* get {name systemaccess email telephone fax objectspace.{ name description } localarea password mailtype } token { "|" ";" ','} ;

 

common syntax

Common_GetBasicOption
Common_GetBasicToken [ as IDENTIFIER ]

Common_GetBasicToken
id  
name  
origdate  
moddate  
moduser  
description  
svnrev  
hidden  
image  
imagedata  
feature[ AdminName ] [. Feature_GetBasicOption]
feature[] [. Feature_GetBasicOption]
feature [. Feature_GetBasicOption]
application [. Menu_GetBasicOption]
super  
admintype  

Edit_Operator
add
remove

Edit_RefOperator
addbefore AdminName set
addafter AdminName set
add
remove
movebefore
moveafter

Edit_AddOperator
addbefore AdminName define
addafter AdminName define
append

Edit_MoveOperator
movebefore
moveafter

Event_Type
action
check

AdminPatternList
AdminNamePattern {, AdminNamePattern}

AdminNamePattern
*
PATTERNIDENTIFIER
STRINGVAL
AdminName

GenericPatternList
GenericPattern {, GenericPattern}

GenericPattern
*
IDENTIFIER
PATTERNIDENTIFIER
GenericValue

AdminActor
user AdminName
team AdminName
assignment AdminName

AdminName
IDENTIFIER
QUOTED_STRING
SQUOTED_STRING

GenericValue
DATETIME
GenericNumber
GenericString
BOOLEANVAL

GenericString
STRINGVAL
QUOTED_STRING
SQUOTED_STRING

GenericNumber
NUMBER
REALNUMBER

Filter_Option
moddate Date_Range
application AdminNamePattern

Date_Range
=  DATETIME  
!= DATETIME
  
<  DATETIME
  
>  DATETIME
  
<= DATETIME
  
>= DATETIME
  
in [ DATETIME , DATETIME ]
  
in ( DATETIME , DATETIME ]
  
in [ DATETIME , DATETIME )
  
in ( DATETIME , DATETIME )  

Token_Option
token { Token_Separator { Token_Separator } }
token Token_Separator

Token_Separator
QUOTED_STRING
SQUOTED_STRING
IDENTIFIER
STRINGVAL
json
json-
json+
xml
xml-
xml+

ExportFile_Option
exportfile FileName [append] [xml | json ]

ImportFile_Option
importfile FileName [xml | json |emxxml]

LogFile_Option
logfile FileName [append]

FileName
QUOTED_STRING
SQUOTED_STRING

basic elements
grammar rules
[ ] = optional element - only one item is allowed : ( 0 or 1 )
{ } = optional element - more than one is allowed : ( 0 or N )
/ = alternative
= one of ...
   
  all bold texts represent keywords or command syntax

IDVAL
#<5 dec digits [ 0-9 ]>-<8 hex digits [ 0-9 A-F ]>
  example:
  #00020-34F2A80E

COMMENT
// <any character until the end of the line(\n \r)>
  example:
  // My single line comment

LONGCOMMENT
/* <any character> */
 

example:
  /* My multi line comment starts here
  continue here
  and finish here */

DATETIME
<year 4 digits>[ - /. ]<month 2 digits>[ - /. ]<day 2 digits>
  examples:
   2009-12-23    2009/03/19   2009.11.14
<year 4 digits>[ - /. ]<month 2 digits>[ - /. ]<day 2 digits> <hours>:<minutes>:[<seconds>]
  examples:
   2009-12-23 10:23   2009/03/19 16:03:34  2009.11.14 00:20:04

NUMBER
[+-]<decimal digits [ 0-9 ]>
  examples:
   -1203   +276   25

BOOLEANVAL
true / false

REALNUMBER
[+-]<decimal digits [ 0-9 ]>.<decimal digits [ 0-9 ]>[E(+-)<esponent [0-9]>]
  example:
   -37.837   +2.3874   13.887   1.4862E-04

QUOTED_STRING
"<any character>"
  example:
   "my quoted string"

SQUOTED_STRING
'<any character>'
  example:
   'my single quoted string'

IDENTIFIER
<one or more of [ a-z A-Z ]><zero or more of [ a-z A-Z 0-9 _ ]>
  example:
   Var1    object_Name_02

VARIABLE
$<one o more of [ a-z A-Z 0-9 ]><zero or more of [ a-z A-Z 0-9 _ ]>
 

example:
   $1   $var_02    $1b

STRINGVAL
<one or more of [ a-z A-Z 0-9 -_ $ ? @ | ~ % & / = : + \ # ' ]>
  a string not recognized as identifier

PATTERNIDENTIFIER
<a string with * (match 0 or more characters) and ? (match 1 character) wildcards>
  example:
   mypa*er?_ide?ti*

© 2008-2015 MS Enterprise Solutions | Website Templates by IceTemplates.com
Please Read: Privacy Policy and Terms of Use